sub:assertion {
  sub:get-user-stats dct:description "This query returns some general user statistics in the form of number of valid/invalidated/accepted nanopublications published." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get some general user statistics" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/meta> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dct: <http://purl.org/dc/terms/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix bibo: <http://purl.org/ontology/bibo/>
prefix pav: <http://purl.org/pav/>

select ?key ?value where {
{
select ?key (count(?np) as ?value) where {

  #==================== MULTI-VALUE PLACEHOLDER =====================#------ config: ------
  { select ?pkh {                                                    # <- VAR pkh
    bind(if(?__pubkeyhashes = \"\", ?unbound, ?__pubkeyhashes) as ?vs) # <- VAR __pubkeyhashes
    {select*{optional{?a ?b ?c}}limit 1} # (for some Virtuoso ver.)  #
    values ?x {0 1 2 3 4 5 6 7 8 9} values ?y {0 1 2 3 4 5 6 7 8 9}  #
    bind((10*?x)+?y as ?n) # (works up to a maximum of 100 values)   #
    bind(\" \" as ?sep) # (separator as single regex-compatible char)  # <- CONST sep
    bind(concat(\"^([^\",?sep,\"]*\",?sep,\"){\",str(?n),\"}\") as ?p)       #
    bind(concat(?sep,\".*\") as ?p0)                                   #
    filter(if(?n=0,true,regex(?vs,?p))) # (?n=0 check for Viruoso)   #
    bind(replace(if(?n=0,?vs,replace(?vs,?p,\"\")),?p0,\"\") as ?pkh)    # <- VAR pkh
    filter(exists {?any_np npa:hasValidSignatureForPublicKeyHash ?pkh })  # Filter out the hashes for which no repo exists; try to do this better with future versions of Nanopub Query
  } }                                                                #
  #==================================================================#---------------------
  bind(uri(concat(\"https://w3id.org/np/l/nanopub-query-1.1/repo/pubkey/\", ?pkh)) as ?pubkeyservice)
  bind(if(bound(?pkh), ?pubkeyservice, <https://w3id.org/np/l/nanopub-query-1.1/repo/meta>) as ?service)
 
  service ?service { select distinct ?np ?invalidated { optional {
    graph npa:graph {
      ?np npa:hasValidSignatureForPublicKey ?pubkey .
      ?np dct:creator ?_userid_iri .
      bind( exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . } as ?invalidated )
    }
  } } }

bind(if(?invalidated,\"invalidatedNpCount\",\"validNpCount\") as ?key)
values ?key { \"invalidatedNpCount\" \"validNpCount\" }

}
group by ?key ?invalidated
}
union
{
select ?key (sum(?npcount) as ?value) where {

bind(\"acceptedNpCount\" as ?key)

optional { <x:> <x:> ?_userid_iri }  # ensure grlc is picking up the placeholder

values ?npType {
  <https://w3id.org/kpxl/pensoft/rio/terms/RIOJournalNanopub>
  <https://w3id.org/kpxl/pensoft/bdj/terms/BiodiversityDataJournalNanopub>
  <https://w3id.org/kpxl/ios/ds/terms/DataScienceNanopub>
}
bind(uri(concat(\"https://w3id.org/np/l/nanopub-query-1.1/repo/type/\", sha256(str(?npType)))) as ?service)

service ?service { select (count(distinct ?np) as ?npcount) where { optional {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    ?np np:hasPublicationInfo ?i .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
  }
  { {
    graph ?i { ?np pav:authoredBy ?_userid_iri . }
  } union {
    graph ?i {
      ?np bibo:authorList ?authorList .
      ?authorList ?hasElement ?_userid_iri .
      filter(strstarts(str(?hasElement), str(rdf:_)))
    }
  } }
} }
group by ?np
} }
group by ?key
}
}
order by ?key""" .
}