sub:assertion {
  sub:get-latest-rio-nanopubs dct:description "This query returns the final nanopublications that have been accepted at the RIO Journal." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get latest nanopublications at RIO Journal" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/9d535811c66bd27b8c44331f56c51b3290b40e8e26c1b1638b4de5d4b13ec159> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix oa: <http://www.w3.org/ns/oa#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix pav: <http://purl.org/pav/>
prefix bibo: <http://purl.org/ontology/bibo/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?np ?label (coalesce(?firstAuthor, min(?author), min(?creator)) as ?mainAuthor) (if(if(count(distinct ?author)>0, count(distinct ?author), count(distinct ?creator)) > 1, \" et al.\", \"\") as ?authorEtAl) ?timestamp (substr(str(?timestamp), 0, 11) as ?date) where {
  graph npa:graph {
    ?np dct:created ?timestamp .
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    ?np rdfs:label ?label .
    ?np np:hasAssertion ?a .
    ?np np:hasPublicationInfo ?i .
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
  }
  optional {
    graph ?i { ?np pav:authoredBy ?author . }
  }
  optional {
    graph ?i {
      ?np bibo:authorList ?authorList .
      ?authorList ?hasElement ?author .
      filter(strstarts(str(?hasElement), str(rdf:_)))
    }
  }
  optional {
    graph ?i {
      ?np bibo:authorList ?authorList .
      ?authorList rdf:_1 ?firstAuthor .
    }
  }
}
group by ?np ?label ?timestamp
order by desc(?timestamp)
limit 10""" .
}