sub:assertion {
  sub:get-accepted-nanopubs-by-author dct:description "This query returns all nanopublications accepted at a journal by the given author." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all nanopublications by given author" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/empty> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix bibo: <http://purl.org/ontology/bibo/>
prefix pav: <http://purl.org/pav/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select ?np ?label ?npType ?timestamp where {

values (?npType ?pubkeys) {
  (<https://w3id.org/kpxl/pensoft/rio/terms/RIOJournalNanopub> \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
  (<https://w3id.org/kpxl/pensoft/bdj/terms/BiodiversityDataJournalNanopub> \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
  (<https://w3id.org/kpxl/ios/ds/terms/DataScienceNanopub> \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
}

bind(uri(concat(\"https://w3id.org/np/l/nanopub-query-1.1/repo/type/\", sha256(str(?npType)))) as ?service)

service ?service { select distinct ?np ?label ?timestamp where {
  graph npa:graph {
    ?np dct:created ?timestamp .
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    ?np rdfs:label ?label .
    ?np np:hasAssertion ?a .
    ?np np:hasPublicationInfo ?i .
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    filter(contains(?pubkeys, sha256(?pubkey)))
  }
  { {
    graph ?i { ?np pav:authoredBy ?_author_iri . }
  } union {
    graph ?i {
      ?np bibo:authorList ?authorList .
      ?authorList ?hasElement ?_author_iri .
      filter(strstarts(str(?hasElement), str(rdf:_)))
    }
  } }
}
group by ?np ?label ?timestamp
} }
order by desc(?timestamp)""" .
}