sub:assertion {
  sub:get-3pff-events-for-user dct:description "Returns all 3PFF events for a given user, including the role they had in each event." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get 3PFF events for user" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix dct: <http://purl.org/dc/terms/>
prefix tpff: <https://w3id.org/fair/3pff/>
prefix schema: <http://schema.org/>

select ?event ?event_label (sample(?ev_name) as ?event_name) (sample(?ev_date) as ?event_date) ?roles_multi_iri ?roles_label_multi ?nps_multi_iri ?nps_label_multi where {
  {
    select ?event (replace(str(?event), \"^.*/\", \"\") as ?event_label) (group_concat(str(?role); separator=\" \") as ?roles_multi_iri) (group_concat(?role_label; separator=\"\\n\") as ?roles_label_multi) (group_concat(str(?latest_np); separator=\" \") as ?nps_multi_iri) (group_concat(\"^\"; separator=\"\\n\") as ?nps_label_multi) where {
      {
        select ?event ?role ?role_label (sample(?np) as ?latest_np) where {
          values (?role ?role_label) {
            (tpff:participatedAsParticipantIn \"Participant\")
            (tpff:participatedAsFacilitatorIn \"Facilitator\")
            (tpff:participatedAsTrainerIn \"Trainer\")
            (tpff:participatedAsFacilitatorAssistantIn \"Facilitator Assistant\")
            (tpff:participatedAsTrainerAssistantIn \"Trainer Assistant\")
            (tpff:participatedAsImplementerIn \"Implementer\")
            (tpff:participatedAsImplementerAspirantIn \"Implementer Aspirant\")
          }
          graph npa:graph {
            ?np npx:hasNanopubType ?role .
            ?np dct:creator ?_user_iri .
            ?np npa:hasValidSignatureForPublicKeyHash ?pk .
            filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pk . }
            ?np np:hasAssertion ?a .
            ?np dct:created ?date .
          }
          graph ?a {
            ?_user_iri ?role ?event .
          }
          filter not exists {
            graph npa:graph {
              ?np2 npx:hasNanopubType ?role .
              ?np2 dct:creator ?_user_iri .
              ?np2 npa:hasValidSignatureForPublicKeyHash ?pk2 .
              filter not exists { ?npx2 npx:invalidates ?np2 ; npa:hasValidSignatureForPublicKeyHash ?pk2 . }
              ?np2 np:hasAssertion ?a2 .
              ?np2 dct:created ?date2 .
              filter(?date2 > ?date)
            }
            graph ?a2 {
              ?_user_iri ?role ?event .
            }
          }
        }
        group by ?event ?role ?role_label
      }
    }
    group by ?event
  }
  optional {
    graph npa:graph {
      ?enp npx:introduces ?event .
      ?enp npa:hasValidSignatureForPublicKeyHash ?epk .
      filter not exists { ?enpx npx:invalidates ?enp ; npa:hasValidSignatureForPublicKeyHash ?epk . }
      ?enp np:hasAssertion ?ea .
    }
    graph ?ea {
      ?event rdfs:label ?ename .
      optional { ?event dct:date ?dateDct . }
      optional { ?event schema:startDate ?dateSchema . }
    }
  }
  bind(coalesce(?dateDct, strBefore(str(?dateSchema), \"T\")) as ?ev_date)
  bind(replace(?ename, \"^[^|]*\\\\| ?\", \"\") as ?ev_name)
}
group by ?event ?event_label ?roles_multi_iri ?roles_label_multi ?nps_multi_iri ?nps_label_multi
order by desc(sample(?ev_date))""" .
}