sub:assertion {
  sub:find-fdos dct:description "This query returns all FDOs that have the given search string in their labels." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Find FDOs by label search" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix schema: <http://schema.org/>
prefix fdof: <https://w3id.org/fdof/ontology#>

select ?fdo ?profile ?np ?label ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np dct:created ?date .
    values ?type { fdof:FAIRDigitalObject npx:RoCrateNanopub }
    ?np npx:hasNanopubType ?type .
    ?np npx:introduces ?fdo .
    ?np np:hasAssertion ?assertion .
    ?np rdfs:label ?label .
    filter(contains(lcase(?label), ?_query))
  }
  graph ?assertion { {
      ?fdo dct:conformsTo ?profile .
    } union {
      ?metadata dct:conformsTo ?profile .
      ?metadata schema:about ?fdo .
  } }
} order by desc(?date)""" .
}