sub:assertion {
  sub:get-all-iadopt-variables dct:description "Returns all I-Adopt variables with their decomposition into observable property, entity of interest, matrix, and context object." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all I-Adopt variables" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/dbf3e4836e0529b98c8e70684a03a3fb3a7b48dfa7829747dd978f2b7249ada1> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix iadopt: <https://w3id.org/iadopt/ont/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>

select ?variable ?variable_label ?property ?property_label ?entity ?entity_label ?matrix ?matrix_label ?context ?context_label ?creator ?np (\"^\" as ?np_label) ?date where {
  graph npa:graph {
    ?np npx:hasNanopubType iadopt:Variable .
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    ?np npx:introduces ?variable .
    ?np npx:signedBy ?creator .
  }
  graph ?a {
    ?variable a iadopt:Variable .
    optional { ?variable rdfs:label ?variable_label . }
    optional {
      ?variable iadopt:hasObservableProperty ?property .
      optional { ?property rdfs:label ?property_label . }
    }
    optional {
      ?variable iadopt:hasObjectOfInterest ?entity .
      optional { ?entity rdfs:label ?entity_label . }
    }
    optional {
      ?variable iadopt:hasMatrix ?matrix .
      optional { ?matrix rdfs:label ?matrix_label . }
    }
    optional {
      ?variable iadopt:hasContextObject ?context .
      optional { ?context rdfs:label ?context_label . }
    }
  }
}
order by desc(?date)""" .
}