sub:assertion {
  sub:fips-by-domain dct:description "This query returns the FAIR Implementation Profiles (FIPs) per scientific domain." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "FIP by domain" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/6a09747868afc83837e38d1bac79362fbcc3e2032cff2f2d244f4e24cbd085c6> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix fip: <https://w3id.org/fair/fip/terms/>
prefix search: <http://www.openrdf.org/contrib/lucenesail#>

select distinct ?fipnp ?fip ?fip_label ?community (min(?communitylabel) as ?community_label) (group_concat(distinct ?domain; separator=\" \") as ?domains) where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey ;
      dct:created ?date ;
      npx:hasNanopubType fip:FAIR-Implementation-Community ;
      np:hasAssertion ?a .
    ?np npx:introduces|npx:describes ?community .
    ?np dct:created ?date . filter(str(?date) > \"2022\")
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
  }
  graph ?a {
    ?community a fip:FAIR-Implementation-Community ;
      rdfs:label ?communitylabel ;
      fip:has-research-domain ?domain .
    ?community fip:has-research-domain ?domainx .
  }
  graph <http://purl.org/np/RArRAOwj4QOppEPCR8WVvOBmrX7oRKOrPi-asX-7AY66I#assertion> {
    ?domainx rdfs:subClassOf* ?_domain_iri .
  }
  service <https://w3id.org/np/l/nanopub-query-1.1/repo/type/92efd7a0ea4be4e01ec0817ccec87f975203b30addcc3166a204498ffed73b66> {  # (https://w3id.org/fair/fip/terms/FAIR-Implementation-Profile)
    select ?fipnp ?fip ?fip_label ?community {
      graph npa:graph {
        ?fipnp np:hasAssertion ?fa .
        optional { ?fipnp rdfs:label ?fip_label . }
        ?fipnp npx:introduces|npx:describes ?fip .
        ?fipnp npa:hasValidSignatureForPublicKey ?fpubkey .
        ?fipnp npx:hasNanopubType fip:FAIR-Implementation-Profile .
        filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
        filter not exists { ?fipnpx npx:invalidates ?fipnp ; npa:hasValidSignatureForPublicKey ?fpubkey . }
      }
      graph ?fa {
        ?fip fip:declared-by ?community .
      }
    }
  }
}
group by ?fipnp ?fip ?fip_label ?community""" .
}