sub:assertion {
  sub:get-3pff-events dct:description "Returns a list of all events related to the Three Point FAIRification Framework (3PFF)" ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get 3PFF Events" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/1c6aa07996de9244076dbdbf96515ae280fb28a8a0cc49f7b0b8c819bc8d54cf> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix tpff: <https://w3id.org/fair/3pff/>
prefix schema: <http://schema.org/>

select (?event as ?Event_ID) (?eventShortName as ?Event_ID__label) (?eventLongName as ?Event_Name) (?eventDate as ?Date) (group_concat(distinct ?eventOrganizer; separator=\" \") as ?Organizers) (group_concat(distinct ?eventFacilitator; separator=\" \") as ?Facilitators) (group_concat(distinct ?eventMoreInfoLink; separator=\" \") as ?More_Info) (?np as ?Source) where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    ?np dct:created ?npDate .
    ?np dct:creator ?npCreator .
    ?np np:hasAssertion ?assertion .
    ?np npx:introduces ?event .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
  }
  graph ?assertion {
    ?event a tpff:3PFF-event .
    ?event rdfs:label ?eventName .
   
    # Date Handling: Check for both predicates
    optional { ?event dct:date ?dateDct . }
    optional { ?event schema:startDate ?dateSchema . }
    bind(coalesce(?dateDct, ?dateSchema) as ?eventDate)
   
    bind(replace(str(?eventName), ' ?\\\\|.*$', '') as ?eventShortName)
    bind(replace(str(?eventName), '^([A-Z0-9]{2,3}).*$', '$1') as ?eventSeries)
    bind(replace(str(?eventName), '^.*\\\\| ?(.*)$', '$1') as ?eventLongName)

    optional {
      ?event tpff:has-event-organizer ?eventOrganizer .
    }
    optional {
      ?event tpff:has-event-facilitator ?eventFacilitator .
    }
    optional {
      ?event rdfs:seeAlso ?eventMoreInfoLink .
    }
  }
}
group by ?event ?eventShortName ?eventLongName ?eventDate ?np
order by desc(?eventDate)""" .
}