sub:assertion {
  sub:get-concepts-of-skos-scheme dct:description "This query returns all concepts that specify to be in the given SKOS scheme." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get the concepts of a SKOS scheme" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/af79dec054ac75f59327aa4e560e3ed0c243130f9852d4e7027aee5beefed2f3> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix owl: <http://www.w3.org/2002/07/owl#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>

select ?concept ?label ?broaderConcept (?definition as ?description) ?np (group_concat(?flagLabel; separator=\" \") as ?flags) where {
  values ?_scheme_multi_iri {}
  graph npa:graph {
    ?np npx:hasNanopubType skos:Concept .
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
    ?np dct:created ?date .
    ?np npx:introduces ?concept .
    ?np np:hasAssertion ?a .
  }
  optional {
    graph npa:graph {
      values (?flag ?flagLabel) { ( npx:ExampleNanopub \"Example\") ( npx:DraftNanopub \"Draft\") }
      ?np npx:hasNanopubType ?flag .
    }
  }
  graph ?a {
    ?concept skos:inScheme ?_scheme_multi_iri .
    optional { ?concept skos:broader ?broaderConcept . }
    optional { ?concept skos:prefLabel ?label . }
    optional { ?concept skos:definition ?definition . }
  }
}
group by ?concept ?label ?broaderConcept ?definition ?np
order by ?label""" .
}