sub:assertion {
  sub:get-highlighted-implied-relations dct:description "This query returns all highlighted implied relations published as Web Annotations." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get highlighted implied relations" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/73524a837856cc57da54076eb9eb5088109df69a20f3ca0b1625634f16a1ed8a> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix oa: <http://www.w3.org/ns/oa#>

select ?subject ?predicate ?object ?source ?np ?label ?annotator ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    ?np npx:introduces ?annotation .
    ?np npx:signedBy ?annotator .
    optional { ?np rdfs:label ?label }
  }
  graph ?a {
    ?annotation a oa:Annotation .
    ?annotation oa:motivatedBy oa:highlighting .
    ?annotation oa:hasTarget ?target .
    optional { ?target oa:hasSource ?sourcex . }
    bind(coalesce(?sourcex, ?target) as ?source)
    ?annotation oa:hasBody ?relation .
    ?relation rdf:subject ?subject .
    ?relation rdf:predicate ?predicate .
    ?relation rdf:object ?object .
  }
}
order by desc(?date)""" .
}