sub:assertion {
  sub:get-all-fdos dct:description "This query returns all FDOs, including Handle-based ones and RO-Crates." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all FDOs" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix schema: <http://schema.org/>

select ?fdo ?np ?label ?profile ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np dct:created ?date .
    values ?type { <https://w3id.org/fdof/ontology#FAIRDigitalObject> <http://purl.org/nanopub/x/RoCrateNanopub> }
    ?np npx:hasNanopubType ?type .
    ?np npx:introduces ?fdo .
    ?np np:hasAssertion ?a .
    optional { ?np rdfs:label ?label }
  }
  graph ?a {
    {
      ?fdo dct:conformsTo ?profile .
    } union {
      ?meta dct:conformsTo ?profile .
      ?meta schema:about ?fdo .
    }
  }
} order by desc(?date)""" .
}